写个bat批处理,整个目标文件夹内文件重排序列并遍历复制

发布网友 发布时间：2022-04-24 16:25

我来回答

共1个回答

热心网友 时间：2023-10-22 12:24

00合成序列详情到指定目录.bat

@echo off & color 0a & title %~n0 By 依梦琴瑶
setlocal enabledelayedexpansion

for %%a in (春 夏 秋 冬) do (
    pushd %%a
        for /d %%b in (*) do (
            set Num=0
            for %%c in (40优化 50腿模 60详情) do (
                if exist "..\%%c\%%b" for /r %%d in ("..\%%c\%%b\*.jpg") do (
                    set /a Num+=1
                    if !Num! lss 10 (set Number=60!Num!) else (set Number=6!num!)
                    echo 正在拷贝“%%c∶%%~nxd”至“%%a∶%%b”目录中。。。
                    copy "%%~d" "%%b\!Number!.jpg" >nul
                )
            )
        )
    popd
)
echo 拷贝完毕，请按任意键退出。
pause>nul
exit

01复制650图片到指定目录.bat

@echo off & color 0a & title %~n0 By 依梦琴瑶
echo 请选择要拷贝的文件：
echo    1、9.jpg      2、650.jpg      3、全部
echo, & set /p Str=输入编号后回车 
set Sfile=9.jpg 650.jpg
if "%Str%"=="1" set Sfile=9.jpg
if "%Str%"=="2" set Sfile=650.jpg
if "%Str%"=="3" set Sfile=9.jpg 650.jpg


echo, & echo, & echo 请选择要处理的目录：
echo    1、春    2、夏    3、秋    4、冬    5、全部
echo, & set /p Sdir=输入编号后回车 
set Sfolder=春 夏 秋 冬
if "%Sdir%"=="1" set Sfolder=春
if "%Sdir%"=="2" set Sfolder=夏
if "%Sdir%"=="3" set Sfolder=秋
if "%Sdir%"=="4" set Sfolder=冬
if "%Sdir%"=="5" set Sfolder=春 夏 秋 冬

echo, & echo, & echo 正在把“%Sfile%”拷贝至“%Sfolder%”目录中的相关目录里。。。
for %%a in (%Sfolder%) do (
    pushd %%a
        for /d %%b in (*) do (
            for %%c in (%Sfile%) do (
                copy ..\%%c "%%b\"
            )
        )
    popd
)
echo, & echo 拷贝完毕，请按任意键退出。
pause>nul
exit

以上代码已根据你新的要求编写。